
##############################################################################
#
# Copyright (c) 2003-2017 by The University of Queensland
# http://www.uq.edu.au
#
# Primary Business: Queensland, Australia
# Licensed under the Apache License, version 2.0
# http://www.apache.org/licenses/LICENSE-2.0
#
# Development until 2012 by Earth Systems Science Computational Center (ESSCC)
# Development 2012-2013 by School of Earth Sciences
# Development from 2014 by Centre for Geoscience Computing (GeoComp)
#
##############################################################################

Import('*')
local_env = env.Clone()

if local_env['cppunit'] and local_env['cuda']:
    # get the test source file names
    sources = Glob('*.cpp')
    testname='ripley_UnitTest'

    # build the executable
    local_env.PrependUnique(LIBS=env['ripley_libs']+env['cppunit_libs'])

    if env['openmp']:
        local_env.Append(CPPDEFINES = ['THRUST_HOST_SYSTEM=THRUST_HOST_SYSTEM_OMP'])

    local_env['NVCCFLAGS'] += ' -w'
    local_env['SHNVCCFLAGS']  += ' -w'
    local_env.Append(CPPDEFINES = ['THRUST_DEVICE_SYSTEM=THRUST_DEVICE_SYSTEM_CUDA'])
    #TODO: This needs a config option:
    local_env.Append(CPPDEFINES = ['CUSP_USE_TEXTURE_MEMORY'])

    program = local_env.Program(testname, sources)

    # run the tests - but only if test_targets are stale
    local_env.RunUnitTest(testname)

    # add unit test to target alias
    Alias('build_tests', program)
    Alias("run_tests", testname+'.passed')

    # add a group of tests
    from grouptest import GroupTest
    tgroup=GroupTest("ripleycpp", "$BINRUNNER ", (), "", "$BUILD_DIR/ripley/test", ('./'+testname,))
    TestGroups.append(tgroup)

# configure python unit tests
local_env.SConscript('python/SConscript', duplicate=0)

