%{
#include "replacement.h"
#include "macros.h"
#include "ascii.h"
%}

%ignore-case
%struct-type
%omit-struct-type
%compare-lengths
%readonly-tables
%null-strings
%includes
%define lookup-function-name gumbo_get_svg_tag_replacement
%define slot-name from
%define initializer-suffix ,(char*)0
StringReplacement;

%%
"altglyph", "altGlyph"
"altglyphdef", "altGlyphDef"
"altglyphitem", "altGlyphItem"
"animatecolor", "animateColor"
"animatemotion", "animateMotion"
"animatetransform", "animateTransform"
"clippath", "clipPath"
"feblend", "feBlend"
"fecolormatrix", "feColorMatrix"
"fecomponenttransfer", "feComponentTransfer"
"fecomposite", "feComposite"
"feconvolvematrix", "feConvolveMatrix"
"fediffuselighting", "feDiffuseLighting"
"fedisplacementmap", "feDisplacementMap"
"fedistantlight", "feDistantLight"
"feflood", "feFlood"
"fefunca", "feFuncA"
"fefuncb", "feFuncB"
"fefuncg", "feFuncG"
"fefuncr", "feFuncR"
"fegaussianblur", "feGaussianBlur"
"feimage", "feImage"
"femerge", "feMerge"
"femergenode", "feMergeNode"
"femorphology", "feMorphology"
"feoffset", "feOffset"
"fepointlight", "fePointLight"
"fespecularlighting", "feSpecularLighting"
"fespotlight", "feSpotLight"
"fetile", "feTile"
"feturbulence", "feTurbulence"
"foreignobject", "foreignObject"
"glyphref", "glyphRef"
"lineargradient", "linearGradient"
"radialgradient", "radialGradient"
"textpath", "textPath"
